1 files changed, 43 insertions, 0 deletions
diff --git a/xfce4-genmon-plugin/PKGBUILD b/xfce4-genmon-plugin/PKGBUILD
new file mode 100644
index 0000000..4f8e8f8
--- /dev/null
+++ b/xfce4-genmon-plugin/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
+# Contributor: AndyRTR <andyrtr@archlinux.org>
+# Contributor: Tobias Kieslich <tobias (at) archlinux.org>
+
+pkgname=xfce4-genmon-plugin
+pkgver=4.0.1
+pkgrel=1
+pkgdesc="plugin that monitors customizable programs stdout for the Xfce4 panel"
+arch=('x86_64')
+license=('LGPL2.1')
+url="https://goodies.xfce.org/projects/panel-plugins/xfce4-genmon-plugin"
+groups=('xfce4-goodies')
+depends=('xfce4-panel')
+makedepends=('intltool')
+source=(https://archive.xfce.org/src/panel-plugins/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2
+        font-fix.patch)
+sha256sums=('4c6ce37fbe71094548b44862587c2813da991aeaaecff8e572724dbbec83ab86' 'SKIP')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  patch -Np1 -i "$srcdir"/font-fix.patch
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib \
+    --localstatedir=/var \
+    --disable-static \
+    --disable-debug
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et: