1 files changed, 45 insertions, 0 deletions
diff --git a/terminal/PKGBUILD b/terminal/PKGBUILD
new file mode 100644
index 0000000..59bc2ef
--- /dev/null
+++ b/terminal/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
+# Contributor: tobias <tobias funnychar archlinux.org>
+# Contributor: Aurelien Foret <orelien@chez.com>
+
+_pkgname_=xfce4-terminal
+pkgname=terminal
+pkgver=0.8.8
+pkgrel=2
+pkgdesc="A modern terminal emulator primarily for the Xfce desktop environment"
+arch=('x86_64')
+url="https://www.xfce.org/"
+license=('GPL2')
+groups=('xfce4')
+depends=('libxfce4ui' 'vte3' 'hicolor-icon-theme')
+makedepends=('intltool')
+conflicts=('xfce4-terminal')
+replaces=('xfce4-terminal')
+provides=('xfce4-terminal')
+source=(https://archive.xfce.org/src/apps/$_pkgname_/0.8/$_pkgname_-$pkgver.tar.bz2 hotkey.patch)
+sha256sums=('8fba6a60d3a0fee07417ad7c36bf78cc45be1b27f0759e125051aa73f08487fd' 'SKIP')
+
+prepare() {
+  cd "$srcdir/$_pkgname_-$pkgver"
+  patch -p1 -i "$srcdir/hotkey.patch"
+}
+
+build() {
+  cd "$srcdir/$_pkgname_-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib/xfce4 \
+    --localstatedir=/var \
+    --disable-static \
+    --disable-debug
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname_-$pkgver"
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et: