blob: fd67b982f9e3e8a0ce6c156cc2289927bed34ed2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=libwnck
pkgver=2.31.0
pkgrel=2
pkgdesc="Window Navigator Construction Kit"
arch=('x86_64')
license=('LGPL')
depends=('gtk2' 'startup-notification' 'libxres')
makedepends=('libxt' 'intltool' 'gobject-introspection' 'python2')
url="http://www.gnome.org/"
source=(https://download.gnome.org/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz
Unhandled-action-type.patch
WindowActionMenu-unset-window-and-stop-async-events-on-dispose.patch)
sha512sums=('54262a08882021f08f3ba7f2ddfa33fc1f02e391a0f61cf999a50a089e0d277dfe13ab133c1a46e9abf0599bd24c21dacff80b51013cbb1375d2cd71ac9abbe9'
'SKIP'
'1ba6ee8503e71daf103b7285ce0690042ebd86a4b85728a04ff32e6ee5789d2be71ba32149b0c246518bc47a27a233edfa9cfac9eca16cc44b3c6c8d19943423')
prepare() {
cd $pkgname-$pkgver
patch -Np1 -i ../WindowActionMenu-unset-window-and-stop-async-events-on-dispose.patch
patch -Np1 -i ../Unhandled-action-type.patch
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-static
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
#The binaries are shipped in libwnck3
rm -f "${pkgdir}/usr/bin/wnckprop"
rm -f "${pkgdir}/usr/bin/wnck-urgency-monitor"
rmdir "${pkgdir}/usr/bin"
}
|
